import org.lemiesz.buildsrc.Dep
import org.lemiesz.buildsrc.Versions

plugins {
    id 'com.android.library'
    id 'kotlin-android'
    id 'kotlin-kapt'
    id 'androidx.navigation.safeargs.kotlin'
    id 'maven-publish'
}

android {
    compileSdkVersion Versions.compileSdkVer
    buildToolsVersion Versions.buildToolsVer

    defaultConfig {
        //applicationId "org.lemiesz.alib"
        minSdkVersion Versions.minSdkVer
        targetSdkVersion Versions.targetSdkVer

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility Versions.java
        targetCompatibility Versions.java
    }
    kotlinOptions {
        jvmTarget = Versions.jvmTarget
    }
    buildFeatures {
        viewBinding = true
        dataBinding = true
    }

}

dependencies {
    implementation Dep.Kotlin.stdlib
    implementation Dep.AndroidX.coreKtx
    implementation Dep.AndroidX.appCompat
    implementation Dep.AndroidX.constraintLayout
    implementation Dep.AndroidX.Navigation.fragment
    implementation Dep.AndroidX.Navigation.ui
    implementation Dep.AndroidX.preference
    implementation Dep.Google.material
    implementation Dep.Kotlin.atomicfu
    implementation Dep.Coroutines.core
    implementation Dep.AndroidX.Room.runtime
    implementation project(path: ':klib')
    //noinspection GradleDynamicVersion
    testImplementation Dep.JUnit.test
    testImplementation Dep.Kotest.core
    androidTestImplementation Dep.AndroidX.Test.junit
    androidTestImplementation Dep.AndroidX.Test.espresso
    androidTestImplementation Dep.Kotest.core

    kapt Dep.AndroidX.Room.compiler
}

group = 'org.lemiesz.alib'
version = '1.0.5'

afterEvaluate {
    publishing {
        publications {
            // Creates a Maven publication called "release".
            release(MavenPublication) {
                // Applies the component for the release build variant.
                from components.release

                // You can then customize attributes of the publication as shown below.
                groupId = group
                artifactId = 'final'
                version = version
            }
            // Creates a Maven publication called “debug”.
            debug(MavenPublication) {
                // Applies the component for the debug build variant.
                from components.debug

                groupId = group
                artifactId = 'final-debug'
                version = version
            }

        }

        repositories {
            maven {
                // default credentials for a nexus repository manager
                credentials {
                    username 'alib'
                    password 'soHzC04q1zXYDK3KOKuimsXyV56w9LCxXVmfn00LorqFRe7LT1Qc2a6k4Ux6rVxZ'
                }
                // url to the releases maven repository
                url "https://mvn.lemiesz.org/releases"
            }
        }
    }
}